@echo off

REM BIBARTS 1.1, Timo Baumann, 15. Feb 1996; keinerlei Haftung!

set ORT=C:\BIBARTS

if "%1"=="" goto INFO

if not exist %1.tex goto TEXT_EXISTIERT_NICHT

if exist %1.bar GBIBSORT %1.bar %1.phy

if exist %ORT%\GBIBARTS.IST goto GBIBARTS_IST_IST_DA

echo Die Datei GBIBARTS.IST konnte nicht unter %ORT%/GBIBARTS.IST
echo gefunden werden. In GBIBARTS.BAT sollte in "set ORT=[Pfad]"
echo f"ur [Pfad] der absolute Pfad zu GBIBARTS.IST angegeben werden.
echo .
echo "%1.bar" wird jetzt bearbeitet mit den Kommandos in der Befehls-Zeile:
echo            MAKEINDX -l %1.bar
if exist %1.bar MAKEINDX -l %1.bar
goto WEITER

:GBIBARTS_IST_IST_DA
if exist %1.bar MAKEINDX -s %ORT%\GBIBARTS.IST -g -l %1.bar

:WEITER

call GLATEX %1.tex

goto ENDE

:INFO
echo -------------------------------------------------------------------------
echo  BIBARTS 1.1 f"ur LaTeX-Files  m i t  GERMAN.STY und GBIBARTS.STY
echo     Zur Bearbeitung von GBIBARTS.TEX soll zweimal eingegeben werden:
echo               gbibarts  gbibarts
echo     Hiermit werden GLATEX.BAT, GBIBSORT.EXE und MAKEINDX.EXE 
echo     (mit Index-STyle File GBIBARTS.IST) aufgerufen.
echo  Allgemein k"onnen Texte bearbeitet werden durch Eingabe von
echo               GBIBARTS  [ LaTeX-File.TEX [ ohne .TEX angeben ] ]
echo .
echo  BIBARTS.BAT, GBIBARTS.BAT und GBIBSORT.EXE sollten in ein Verzeich-
echo  nis kopiert werden, das sich im PATH des Betriebsystems befindet.
echo -------------------------------------------------------------------------

goto ENDE

:TEXT_EXISTIERT_NICHT
echo Eine Datei "%1.tex" existiert nicht. Bearbeitet werden k"onnen:
dir *.tex /B


:ENDE